仙境傳說|RO私服

標題: openkore 自動精煉的巨集 [打印本頁]

作者: 小喵咪 時間: 2010-12-23 17:01
標題: openkore 自動精煉的巨集
這個openkore 自動精煉的巨集,小喵咪我的作法是先把所有的需要精煉的裝備精練到仙境傳說安全值，之後在此基礎上將全部的裝備精煉+1，如果完成openkore煉金以後再全部+1。之後就讓openkore外掛一直循環直到到達期望的精煉值。這個做法不是直接一個一個的精煉到期望值，衝壞了就換的辦法。太花錢了，所以偶寫了這個openkore腳本給大家看看，只不過沒有加入自動存取的功能，如果大量精煉的話需要手動存取倉。

下面以把奔跑長靴1洞精煉到+7為例：

automacro check0 {                         #用於檢查裝備的是否是待精煉的+0物品，如果是，則調用精練macro to4upgrade進行精煉
  map rachel                               #條件1，不贅述
  equipped shoes 奔跑長靴[1S] [1]          #條件2，不贅述
  timeout 12
  call to4upgrade
}

macro to4upgrade {                         #用於實現與NPC對話，進行精煉的macro
  pause 2                                  #防LAG延時，很重要，沒有就會卡住
  do talk @npc (151 151)                   #與精煉NPC對話，(151 151)是其坐標，請按照自己的實際設置。另外，bot必須放在NPC的附近才能對話
  pause 2                                  #防LAG延時，很重要，沒有就會卡住
  do talk resp 0                            #在NPC對話框裏選擇要精煉的項目，這裡是第一個，所以是"0"。
                                          #注意CONFIG.TXT裏的autoTalkCont要設置為1，否則要手
                                          #動加上“do talk cont”來完成自動對話
}

###全部+4后再把它們全部精煉到+5

automacro change4 {                         #用於更換+4物品的automacro
  map rachel
  zeny >= 2000                            #精煉一次需要2000z，要寫上作爲條件
  inventory "鋁" > 0                         #精煉需要鋁
  inventory "+4 奔跑長靴[1S] [1]" > 0
  inventory "奔跑長靴[1S] [1]" = 0          #如果還有+0的物品則不觸發，先全部+4再來+5。若倉庫或拖車裏還有+0，須手動補充
  equipped shoes none, +5 奔跑長靴[1S] [1]
  timeout 3
  call equip4
}

macro equip4 {
  pause 2
  do eq +4 奔跑長靴[1S] [1]
  pause 2
}

automacro check4 {
  map rachel
  zeny >= 2000
  inventory "鋁" > 0
  equipped shoes +4 奔跑長靴[1S] [1]
  inventory "奔跑長靴[1S] [1]" = 0
  timeout 12
  call to5upgrade
}

macro to5upgrade {
  pause 2
  do talk @npc (151 149)
  pause 2                                  #與NPC對話精煉的步驟，按照實際情況來寫
  do talk resp 0
  pause 2
  do talk resp 0
  pause 2
  do talk resp 0
}

automacro change0 {                         #用於更換+0精煉裝備的automacro。有安全精煉NPC，可以直接免鋁免費把+0物品精煉到+4
  map rachel                               #條件1：處於精煉NPC所在的地圖，這裡是rachel
  inventory "奔跑長靴[1S] [1]" > 0          #條件2：攜帶了一個以上的精煉物品
  equipped shoes none, +4 奔跑長靴[1S] [1] #條件3："shoes"（鞋子）的位置裝備了做好的+4物品或者沒有裝備
  timeout 3                                  #延時，防止LAG引起句集卡住
  call equip0                               #條件全部滿足則調用換裝macro equip0
}

macro equip0 {                               #用於實現更換精煉裝備的macro
  do eq 奔跑長靴[1S] [1]                      #把待精煉的+0物品裝備到身上以便進行精煉
  pause 2                                  #延時，防止LAG引起句集卡住
}

作者: dcyxxt 時間: 2018-10-22 14:28
牛逼。。。学习了～～～

歡迎光臨仙境傳說|RO私服 (http://ro.private-servers-game.com/)